@echo off
:xs
echo 欢迎使用恩格会计软件bat主控面板
echo 注:本程序只能在服务器主机上使用
echo ***导航菜单***
echo ***显示导航:xs
echo ***查看账套:ck
echo ***新建账套:xj
echo ***备份账套:bf
echo ***还原账套:hy
echo ***删除账套:sc
echo ***密码修改:mm
echo ***演示账套:ys
echo ***版本更新:bb
echo clear:清屏；help:帮助；quit:退出
if not exist C:\AppServ\Apache24 goto help
:a1
set /p xh=请输入菜单代码并回车确认：

if %xh%==xs goto xs
if %xh%==ck goto ck
if %xh%==xj goto xj
if %xh%==bf goto bf
if %xh%==hy goto hy
if %xh%==sc goto sc
if %xh%==mm goto mm
if %xh%==ys goto ys
if %xh%==bb goto bb
if %xh%==clear goto clear
if %xh%==help goto help
if %xh%==quit exit

echo --不是有效的内部命令；
goto a1

rem 查看账套
:ck
for /f "delims=" %%i in ('dir /b /ad C:\AppServ\www\accsoft') do (
echo %%i
)
goto a1

rem 新建账套
:xj-
echo --该账套已经存在
:xj
echo quit:退出当前任务
set /p db=请输入新建账套名称：
if %db%==quit goto a1
if exist C:\AppServ\www\accsoft\%db% goto xj-
REM -s获取鼠标输入  -d取回输入结果赋值
file\hhh -s
FOR /f %%i IN ('file\hhh -d') DO IF NOT "%%i"=="" SET pwd=%%i
echo >sql\temp.sql
echo create database %db%;>sql\temp.sql
mysql -uroot -h127.0.0.1 -p%pwd% <sql\temp.sql
if %errorlevel%==1 goto xj
mysql -uroot -h127.0.0.1 -p%pwd% %db%<sql\new.sql
md C:\AppServ\www\accsoft\%db%
xcopy "accsoft" C:\AppServ\www\accsoft\%db% /s/e/y
set h=5
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* accsoft\cnn.php') do (
  if "%%b"=="" (echo,)else set/a h-=1,1/h&&echo,%%b||echo $acc_database='%db%';
))>C:\AppServ\www\accsoft\%db%\cnn.php 2>nul
start http://127.0.0.1/accsoft/%db%/login.php
goto a1

rem 备份账套
:bf
echo quit:退出当前任务
set /p db=请输入需要备份账套名称：
if %db%==quit goto a1
echo 备份路径写法参考：d:/备份.sql
set /p bf=请输入备份账套完整路径：
mysqldump --no-defaults -uroot -h127.0.0.1 -p %db% >%bf%
if %errorlevel%==1 goto bf
start %bf%
goto a1

rem 还原账套
:hy
echo quit:退出当前任务
set /p db=请输入需要还原账套名称：
if %db%==quit goto a1
echo 还原路径写法参考：d:/备份.sql
set /p bf=请输入还原账套完整路径：
mysql -uroot -h127.0.0.1 -p %db% <%bf%
if %errorlevel%==1 goto hy
start http://127.0.0.1/accsoft/%db%/login.php
goto a1

rem 删除账套
:sc
echo 重要提示：删除账套后数据将无法恢复；
echo           删除前请检查数据是否备份。
echo quit:退出当前任务
set /p db=请输入需要删除账套名称：
if %db%==quit goto a1
echo >sql\temp.sql
echo drop database %db%;>sql\temp.sql
mysql -uroot -h127.0.0.1 -p <sql\temp.sql
if %errorlevel%==1 goto sc
rd /s /q C:\AppServ\www\accsoft\%db%
start http://127.0.0.1/accsoft/%db%/login.php
goto a1

rem 演示账套
:ys
mysql -uroot -h127.0.0.1 -p <sql\demo.sql
if %errorlevel%==1 goto ys
md C:\AppServ\www\accsoft\demo
xcopy "accsoft" "C:\AppServ\www\accsoft\demo" /s/e/y
start http://127.0.0.1/accsoft/demo/login.php
goto a1

rem 密码修改
:mm
REM -s获取鼠标输入  -d取回输入结果赋值
file\hhh -s
FOR /f %%i IN ('file\hhh -d') DO IF NOT "%%i"=="" SET pwd=%%i
if %pwd%==quit goto a1
for /f "delims=" %%i in ('dir /b /ad C:\AppServ\www\accsoft') do (
set h=4
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* accsoft\cnn.php') do (
  if "%%b"=="" (echo,)else set/a h-=1,1/h&&echo,%%b||echo $acc_pwd='%pwd%';
))>C:\AppServ\www\accsoft\%%i\cnn.php 2>nul
)
goto a1

rem 版本更新
:bb
start file\版本更新.txt
goto a1

rem 清屏操作
:clear
cls
goto xs

rem 帮助文档
:help
start 软件使用说明书.docx
goto a1

